Grabbing SEOmoz Metrics with F#

#r @"C:\<your-lib-folder>\Newtonsoft.Json.dll"

open System
open System.IO
open System.Net
open System.Web
open Newtonsoft.Json

//
// Note that SEOmoz returns much more data
// than I'm using here, I just wanna keep it
// nice and simple for this blog post!    - Jules
//

/// The serializable Metrics class
type Metrics =
    class
        val mutable uu  : string
        val mutable pda : string
        val mutable upa : string
    end

/// Get the text from a web server over HTTP
let http (url:string) =
   try
        let req    = WebRequest.Create(url)
        use resp   = req.GetResponse()
        use stream = resp.GetResponseStream()
        use reader = new StreamReader(stream)
        let html   = reader.ReadToEnd()
        html
    with
        | :? UriFormatException -> String.Empty
        | :? WebException       -> String.Empty

/// Tidy the URL of the target site for use with SEOmoz
let urlTidy (url:string) =
    match url with
    | _ when url.StartsWith("http://")  -> url.Substring(7, url.Length - 7)
    | _ when url.StartsWith("https://") -> url.Substring(8, url.Length - 8)
    | _                                 -> url

/// Get the full URL for the SEOmoz API
let mozify (url:string, acc:string, exp:string, sign:string) =
        "http://lsapi.seomoz.com/linkscape/url-metrics/"
      + HttpUtility.UrlEncode(urlTidy url)
      + "?AccessID="  + acc
      + "&Expires="   + exp
      + "&Signature=" + sign
      + "&Cols=103079215108"

/// Deserialize the JSON to a Metrics object
let deserialize (json:string) =
    match json with
    | _ when json.Length = 0 -> failwith "Got zero length input!"
    | _ when json.[0] = '['  -> failwith "Got JSON array input!"
    | _                      -> JsonConvert.DeserializeObject<Metrics>(json)

/// Get URL Metrics for the URL
let getMetrics (url:string, acc:string, exp:string, sign:string) =
    let moz = mozify (url, acc, exp, sign)
    let res = http moz
    deserialize res

// let's test this out...
let m = getMetrics("http://www.blogstorm.co.uk",
                   "<your-seomoz-account>",
                   "<your-seomoz-expires>",
                   "<your-seomoz-signature>")

printfn "URL: %s" m.uu
printfn "Domain Authority: %s" m.pda
printfn "Page Authority: %s" m.upa

URL: www.blogstorm.co.uk/
Domain Authority: 64.474430465805
Page Authority: 70.2271529562222